iLogic - Expand Structured Parts List based on Keyword

One of my drafting processes is to create basic engineering drawings for the client.

Depending on the task, the model may contain certain components to be used in the final design.

The Engineering drawing GA will contain a Member Schedule, with associated member marks, these marks are more of a broad stroke, e.g. C1 for a column. The final workshop model may contain numerous C1 columns, each with a unique identifier. e.g. C1-1 and C1-2 (But they are still all C1.) These member marks are accessed via a custom Balloon.

When I create my BOM, I will create 2 member mark fields, ENG1 and ENG2. ENG2 is generally used for Engineering Drawing member marks. e.g. ENG1=C1-1; and ENG2=C1

On occasion these can be nested deeper into the BOM. I then create a small text entry in the BOM called 'EXP' (In other words, Expand Me) this will indicate that when I place a parts list on the drawing, in order for the Balloon to access the correct member mark, the Parts list needs to be formatted correctly. This may entail expanding or collapsing certain levels/rows of the Parts List.

Exploding the parts list has always been a manual process and can sometimes take quite a long time when dealing with a large Parts list.

The following code, will process the Parts List, and for each row containing the work 'EXP' in the Description field, it will expand this row. This will continue until the entire Parts list has been processed.

Its quick and it works well for my requirements.  

Below is quick view of the final model (This is not a final drawing, just an indication of the balloons in place)

Note:
There is a link to the text file at the bottom of the post.

----- Start Of Code -----

Sub Main()

'Title: Parts List Row Expand

'Date: 04/02/2019

'Reg Hasell

'This rule checks the Parts List sequence number

'Looks for the words "EXP" or "exp"

'If found, it will expand the Parts list row

'This will continue untill the entire parts list has been exposed.

'Caveat:

'I am unable to collapse the parts list. This must be done manually.

'--oOo--

'Get the Parts list Sequence Number

oPRTL = InputBox("Choose the Parts List", "Parts List Filter", "1")

'Once done, call the sort and pass the Parts List number through.

Call oQTY(oPRTL)

End Sub

'--------------------------------

Sub oQTY(oPRTL)

        'On Error Resume Next

        ' Set a reference to the drawing document.

        ' This assumes a drawing document is active.

        Dim oDrawDoc As DrawingDocument

        oDrawDoc = ThisApplication.ActiveDocument

        Dim oPartList As PartsList

        '''---------------------

        ' Set a reference to the first parts list on the active sheet.

        'Dim oPartList As PartsList

        'expand the parts list

        oPartList = oDrawDoc.ActiveSheet.PartsLists.Item(oPRTL)

        ' Iterate through the contents of the parts list.

        Dim i As Long

        Dim oRow As PartsListRow

        'Start counting the parts list rows

        'as the parts list grows due to expansion, the row counter will increase.

        Dim FirstRowCount As Integer = oPartList.PartsListRows.Count

        Dim LastRowCount As Integer = 0

        '

        Do Until FirstRowCount = LastRowCount

               FirstRowCount = oPartList.PartsListRows.Count ' Included in the loop.

               For i = 1 To oPartList.PartsListRows.Count

                       'look for the cell titled "Description"      

                       oCell = oPartList.PartsListRows.Item(i).Item("DESCRIPTION")

                       'oCell2  = oPartList.PartsListRows.Item(i).Item("LENGTH") ' left this for possible later use.

                       Try

                               If oCell.Value = "EXP" Or oCell.Value = "exp" Then

                                      oPartList.PartsListRows.Item(i).Expanded = True

                                      'oCell.Value = "EXP"

                               End If

                       Catch ex As Exception

                       End Try

               Next

               'Count the new size of the Parts List

               LastRowCount = oPartList.PartsListRows.Count

        Loop

        MessageBox.Show("All Done", "BOM QTY")

        'End Sub 'Added the repeat for multiple parts lists

        oAgain = MessageBox.Show("Again", "Rinse and Repeat", MessageBoxButtons.YesNo, MessageBoxIcon.Question, MessageBoxDefaultButton.Button2) 'Added rev2

        If oAgain = vbYes

               AGAIN

        End If

End Sub

Sub AGAIN

        Main

End Sub

---End Code ---


Link to text file 

Total Quantity in the Assembly BOM

Hey all.
Lately there have been a few Autodesk forum posts looking to set a total quantity value in the BOM (Bill Of Materials)

I have cobbled some code together from various snippets found on the forum and in the help files to create just that. Unfortunately I cannot give credit to the original author of the file counter.


It is based on the Inventor "iProperties, Project, Project Number" field. This allows duplicates and common parts to be used in multiple assemblies without the total quantity being affected.  Though, on the other hand, if your typical workflow does not involve a new project number, then this will not work for you.

Read only and Content Center parts will not be updated.
The code will also check the Project number field before running, and change it, if so desired.

It is advised that this is run from the GA, and preferably at the end of the build. You can run it as many times as you wish, but it is still a manual process, so if your assembly changes, you need to run the code again to refresh the total QTY field.

A Custom field of #projectnumber_QTY is created and the total quantity of all sub assemblies and parts are counted and the value added to the field. this is then written to each part and assembly.

I did have to manually add a value for the GA, as the lack of the field was causing some issues in the detail drawings.

example:
Clip of a small assembly:

a clip of the same part Custom iProps:

As you can see, the total quantity has been added to the part as a custom field. The same goes for any Sub-Assemblies as well.

This field can now be used wherever and however you wish.

Anyway, till the next time, enjoy.
Don't forget the golden rule, if you use it and improve on it, share it.




***Start of the iLogic code ***
-----------------------------------------

'09/2017

'Reg Hasell.

'This iLogic rule will run though all the items in an assembly and add a QTY field to it.

'The QTY field is based on a programmable project number. (project_QTY)

'Any Content Center items are ignored. (Read Only)

'There is an option to set the project number.

'

'Some of this code has originated from the forum, but I cannot

'remember where I got it from, so I am unable To give credit To the original author.

Sub Main ()

    'Check to see if this document is an assembly.

    oDoc = ThisApplication.ActiveDocument

        If oDoc.DocumentType <> kAssemblyDocumentObject Then

        MessageBox.Show("This rule can only be run in an Assembly file - exiting rule...", "iLogic")

        Return

        End If

    If iProperties.Value("Project", "Project")=""

        oProj = InputBox("Change Project Name", "Project Name", iProperties.Value("Project", "Project"))

        iProperties.Value("Project", "Project")=oProj

    End If

'get the project number of this assembly and use it to build the name of a custom property, i.e. "4100_QTY"

oBOMQTY = CStr(iProperties.Value("Project", "Project")) & "_QTY"

    oQ=MessageBox.Show(oBOMQTY, "Project Number",MessageBoxButtons.YesNoCancel,MessageBoxIcon.Question)

        If oQ=vbYes

        oDone() 'next Sub Routine

        ElseIf oQ=vbNo

        Call oProject 'Option to change the project Number for the GA

        ElseIf oQ=vbCancel

        MessageBox.Show("Cancelled", "iLogic", MessageBoxButtons.OK, MessageBoxIcon.Asterisk, MessageBoxDefaultButton.Button1)

        Return

    End If

End Sub

Sub oDone

oCompDef = ThisDoc.Document.ComponentDefinition ' Don't need this, but I left it in for reference when looking for code snippets.

openDoc = ThisDoc.Document

oBOMQTY = CStr(iProperties.Value("Project", "Project")) & "_QTY"

'Open the document that inventor has in focus right now

    For Each docFile In openDoc.AllReferencedDocuments

    'FNamePos is getting the number of spaces that it takes to get to the

    'very last back slash in the full file name of our document.        

        FNamePos = InStrRev(docFile.FullFileName, "\", -1)       

    

    'We can then take that number (position) and use it to cut off all of the

    'file path that we don't need. In this case, it's the front of the path

    'that we're getting rid of, leaving us with just the file name.

        docFName = Mid(docFile.FullFileName, FNamePos + 1, Len(docFile.FullFileName) - FNamePos)

       

        'Let's make sure that we can even change this part. If we can, then we'll continue.

        If docFile.IsModifiable = True Then

           

            'Because you can only grab the occurrences from an assembly document

            'we need to fill up that empty AssemblyDocument container with an object

            'that we know is definitely an assembly document. Because that was one

            'of the first checks we made up there on this open document, we can safely

            'declare that assemblyDoc (Which is an AssemblyDocument) is equal to

            ' openDoc (Which is just a regular old Document)            

            assemblyDoc = openDoc

           

            'While we're at it, let's go on and define the empty ComponentDefinition container

            '(we named ours assemblyDef) with some sort of content.

            assemblyDef = assemblyDoc.ComponentDefinition

           

            'Now we need to collect every instance of the document against

            'our open assembly and put them all inside of partQty.

            partQty = assemblyDef.Occurrences.AllReferencedOccurrences(docFile)

           

                'Now that we have our collection of instances, we need to populate

                'our target iproperty with the total amount.

               

                'Instead of just throwing that amount in there, let's make sure that

                'the value inside of the target iProperty isn't already equal to our count.

                'If it is equal, then we don't have to change anything (which saves us time!),

                'but if it isn't equal then we will need to change it.

               

                'The Try statement is here because of the next if statement ---

              

                'If we just compare the two values, there is a small chance that our target

                'iProperty is already set to something that is NOT a number, which would create

                'an error (as you can't compare numbers against things that aren't numbers).

                'So, we TRY to complete that if statement, and if there is an error (The CATCH)

                'we just force that target to equal our part qty total.

                Try

                        If partQty.Count <>  iProperties.Value(docFName, "Custom", oBOMQTY) Then               

                        iProperties.Value(docFName, "Custom", oBOMQTY) = partQty.Count

                        '

                       End If                     

                    Catch

                    iProperties.Value(docFName, "Custom", oBOMQTY) = partQty.Count

                End Try

        End If

    Next

'29/01/2016

'I Added the following line to add the value to the GA

' As the lack thereof was causing issues in the detailing environment.

            Try

                oASSYParam= iProperties.Value("Custom",oBOMQTY)

              Catch

                iProperties.Value("Custom",oBOMQTY) = "1"

                    End Try

iLogicVb.UpdateWhenDone = True

MessageBox.Show("Completed" & vbNewLine & "Champion" & vbNewLine & ":-)", "Completed", MessageBoxButtons.OK, MessageBoxIcon.Asterisk, MessageBoxDefaultButton.Button1)

End Sub

Sub oProject

    oProj = InputBox("Change Project Name", "Project Name", iProperties.Value("Project", "Project"))

    iProperties.Value("Project", "Project")=oProj

    Main () 'Loop Back

End Sub